Take a Trip

1 REM VERSION DU 07/09/2010 14h15
5 REM ANDRES LOZANO 2010
10 REM CONTROL D
15 D$= CHR$(4)
20 REM DEFINITION DES COULEURS UTILISEES
25 DIM CL%(8)
30 FOR I= 1 TO 8
35 READ CL%(I)
40 NEXT I
45 BZ%= 3
50 GOSUB 930:REM SPLASH
55 HGR2
60 REM DEBUT
65 TM%= TM% + 1
70 IF (TM% > 10) THEN HGR2:TM%= 0:F%= F% + 1
75 PRINT TM%;
80 IF (F% > 5) THEN GOTO 180:REM FIN
85 RD%= 30:GOSUB 675:REM NOMBREALEA
90 X%= RD%
95 FOR I= 1 TO X%
100 PRINT ".";
105 GOSUB 295:REM CARRE
110 NEXT I
115 RD%= 10:GOSUB 675:REM NOMBREALEA
120 X%= RD%
125 FOR I= 1 TO X%
130 PRINT ".";
135 GOSUB 410:REM GRILLES
140 NEXT I
145 RD%= 5:GOSUB 675:REM NOMBREALEA
150 X%= RD%
155 FOR I= 1 TO X%
160 PRINT ".";
165 GOSUB 195:REM PLEIN
170 NEXT I
175 GOTO 60:REM DEBUT
180 REM FIN
185 GOSUB 1045:REM CREDITS
190 END
195 REM PLEIN
200 GOSUB 860:REM BUZZ
205 GOSUB 890:REM COULEURALEA
210 RD%= 279:GOSUB 675:REM NOMBREALEA
215 X1%= RD%
220 RD%= 191:GOSUB 675:REM NOMBREALEA
225 Y1%= RD%
230 RD%= X1% + 30:GOSUB 675:REM NOMBREALEA
235 X2%= RD%
240 RD%= (Y2% - 25) + 50:GOSUB 675:REM NOMBREALEA
245 Y2%= RD%
250 RD%= 50:GOSUB 675:REM NOMBREALEA
255 X%= RD%
260 FOR J= 1 TO X%
265 GOSUB 690:REM CHECKXY
270 HPLOT X1%,Y1% TO X2%,Y2%
275 Y1%= Y1% + 1
280 Y2%= Y2% + 1
285 NEXT J
290 RETURN
295 REM CARRE
300 GOSUB 860:REM BUZZ
305 GOSUB 890:REM COULEURALEA
310 RD%= 279:GOSUB 675:REM NOMBREALEA
315 X1%= RD%
320 RD%= 191:GOSUB 675:REM NOMBREALEA
325 Y1%= RD%
330 RD%= 40:GOSUB 675:REM NOMBREALEA
335 PL%= RD%
340 X2%= X1%+PL%
345 Y2%= Y1%
350 GOSUB 690:REM CHECKXY
355 HPLOT X1%,Y1% TO X2%,Y2%
360 Y2%= Y2% + PL%
365 GOSUB 690:REM CHECKXY
370 HPLOT TO X2%,Y2%
375 X2%= X2% - PL%
380 GOSUB 690:REM CHECKXY
385 HPLOT TO X2%,Y2%
390 Y2%= Y2% - PL%
395 GOSUB 690:REM CHECKXY
400 HPLOT TO X2%,Y2%
405 RETURN
410 REM GRILLES
415 GOSUB 860:REM BUZZ
420 GOSUB 890:REM COULEURALEA
425 CX%= 1
430 RD%= 100:GOSUB 675:REM NOMBREALEA
435 HX%= RD%
440 RD%= 100:GOSUB 675:REM NOMBREALEA
445 VX%= RD%
450 RD%= 30:GOSUB 675:REM NOMBREALEA
455 NH%= RD%
460 RD%= 20:GOSUB 675:REM NOMBREALEA
465 NV%= RD%
470 REM LARGEUR CASE MAX
475 LC%= INT( HX% / NH% )
480 REM HAUTEUR CASE MAX
485 HC%= INT( VX% / NV% )
490 IF LC% < 1 THEN LC%= 1
495 IF HC% < 1 THEN HC%= 1
500 DX%= INT( (279 - HX%) / 2 )
505 DY%= INT( (191 - VX%) / 2 )
510 RD%= DX% * 2:GOSUB 675:REM NOMBREALEA
515 DX%= RD%
520 RD%= DY% * 2:GOSUB 675:REM NOMBREALEA
525 DY%= RD%
530 X1%= DX%
535 Y1%= DY%
540 X2%= DX%
545 Y2%= DY% + VX%
550 X%= NH% + 1
555 FOR J= 1 TO X%
560 RD%= 10:GOSUB 675:REM NOMBREALEA
565 GOSUB 690:REM CHECKXY
570 IF (RD% < 7) THEN HPLOT X1%,Y1% TO X2%,Y2%
575 X1%= X1% + LC%
580 X2%= X2% + LC%
585 IF (RD% = 6) THEN X2%= X2% + LC%
590 IF (RD% = 5) THEN X2%= X2% - LC%
595 NEXT J
600 X1%= DX%
605 Y1%= DY%
610 X2%= DX% + HX%
615 Y2%= DY%
620 X%= NV% + 1
625 FOR J= 1 TO X%
630 RD%= 10:GOSUB 675:REM NOMBREALEA
635 GOSUB 690:REM CHECKXY
640 IF (RD% < 7) THEN HPLOT X1%,Y1% TO X2%,Y2%
645 Y1%= Y1% + HC%
650 Y2%= Y2% + HC%
655 IF (RD% = 6) THEN Y2%= Y2% + HC%
660 IF (RD% = 5) THEN Y2%= Y2% - HC%
665 NEXT J
670 RETURN
675 REM NOMBREALEA
680 RD%= INT( RND(1) * RD% ) + 1
685 RETURN
690 REM CHECKXY
695 IF X1% < 1 THEN X1%= 1
700 IF X2% < 1 THEN X2%= 1
705 IF Y1% < 1 THEN Y1%= 1
710 IF Y2% < 1 THEN Y2%= 1
715 IF X1% > 279 THEN X1%= 279
720 IF X2% > 279 THEN X2%= 279
725 IF Y1% > 191 THEN Y1%= 191
730 IF Y2% > 191 THEN Y2%= 191
735 RETURN
740 REM PETITEPAUSE
745 FOR Z= 1 TO 800
750 NEXT Z
755 RETURN
760 REM GRANDEPAUSE
765 FOR Z= 1 TO 2000
770 NEXT Z
775 RETURN
780 REM CENTRAGETEXTE
785 L%=LEN(S$):LF%= INT( (40 - L%) / 2 ) :REM CENTRE LE TEXTE
790 HTAB(LF%+1):VTAB(VT%)
795 RETURN
800 REM VIDETEXTE
805 REM POUR VIDER LA PARTIE TEXT
810 FOR Z= 1 TO 5
815 PRINT
820 NEXT Z
825 RETURN
830 REM BEEP
835 IF (BP% < 2) THEN BP%= 1
840 FOR Z= 1 TO BP%
845 PRINT CHR$(7);
850 NEXT Z
855 RETURN
860 REM BUZZ
865 IF (BZ% < 2) THEN BZ%= 1
870 FOR Z= 1 TO BZ%
875 XS= PEEK(49200):REM SIMPLE SON DE CLIC
880 NEXT Z
885 RETURN
890 REM COULEURALEA
895 AC%= INT( RND(1) * 8) + 1:REM COULEUR ALEATOIRE
900 HCOLOR= CL%(AC%):AC%= CL%(AC%)
905 RETURN
910 REM MEMOIRELIBRE
915 ML=FRE(1)
920 PRINT "MEMOIRELIBRE: ";ML+65536
925 RETURN
930 REM SPLASH
935 REM ECRAN D'ACCUEIL
940 TEXT:HOME
945 GOSUB 830:REM BEEP
950 S$= "SANS TITRE"
955 VT%= 5:REM HAUTEUR TEXTE DEPART
960 GOSUB 780:REM CENTRAGETEXTE
965 PRINT S$
970 S$= "BY ANDRES AKA LOZ"
975 VT%= VT%+2
980 GOSUB 780:REM CENTRAGETEXTE
985 PRINT S$
990 S$= "2010"
995 VT%= VT%+2
1000 GOSUB 780:REM CENTRAGETEXTE
1005 PRINT S$
1010 S$= "LOADING"
1015 VT%= VT%+2
1020 GOSUB 780:REM CENTRAGETEXTE
1025 PRINT S$
1030 GOSUB 760:REM GRANDEPAUSE
1035 HTAB(1):VTAB(22)
1040 RETURN
1045 REM CREDITS
1050 REM ECRAN D'ACCUEIL
1055 TEXT:HOME
1060 GOSUB 830:REM BEEP
1065 S$= "FIN"
1070 VT%= 5:REM HAUTEUR TEXTE DEPART
1075 GOSUB 780:REM CENTRAGETEXTE
1080 PRINT S$
1085 S$= "BY ANDRES AKA LOZ"
1090 VT%= VT%+2
1095 GOSUB 780:REM CENTRAGETEXTE
1100 PRINT S$
1105 S$= "2010"
1110 VT%= VT%+2
1115 GOSUB 780:REM CENTRAGETEXTE
1120 PRINT S$
1125 HTAB(1):VTAB(22)
1130 RETURN
1135 REM COLORS 0 BLACK, 1 GREEN, 2 VIOLET (MAGENTA), 3 WHITE, 4 BLACK, 5 ORANGE, 6 BLUE
1140 DATA 1,2,3,4,4,4,5,6
1145 REM TOTAL LIGNES DE CODE:229 TOTAL DE CARACTERES :4861

# vimeo.com/14770102 Uploaded 334 Plays / / 0 Comments Watch in Couch Mode

Follow

Take a Trip

Dylan Tull Gunnett

Shout Box

Browse This Channel

Channels are a simple, beautiful way to showcase and watch videos. Browse more Channels. Channels